# Issue with the IDE

**URL:** <https://hyperxtalk.discourse.group/t/issue-with-the-ide/164>\
**Category:** General\
**Created:** [August 1, 2026, 8:45am UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164 "2026-08-01T08:45:33Z")\
**Posts on this page:** 14\
**Page:** 1

<div class="post-metadata">

**Author:** ![Skids](https://sea1.discourse-cdn.com/flex037/user_avatar/hyperxtalk.discourse.group/skids/32/106_2.png) [@Skids](https://hyperxtalk.discourse.group/u/Skids)\
**Post date:** [August 1, 2026, 8:45am UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164/1 "2026-08-01T08:45:33Z")

</div>

While convalescing I have been entertaining myself by using HyperXtalk every day this past three weeks. From time to time one or both of two issues appear. The first dates back to Livecode: the IDE stack grows in height so that there is no way of shrinking it back to a usable size. My solution is to run “set the height of the mousestack to 150” from the message box. While this works it may trigger the second issue which is that the lower portion of the IDE window goes AWOL:

 ![Screenshot 2026-08-01 at 09.32.35](https://us1.discourse-cdn.com/flex037/uploads/hyperxtalk/original/1X/94e3003c42da624fce46b951859684d310426d41.png)

The two parallel lines and the variables , breakpoints etc are missing. This state persists following a restart and or a complete computer restart. When a restart is performed then the full window is displayed for a very short while and then the unadorned version is displayed.

To recover to normal I perform a search and replace across stack and its stack files which displays the results in the normal full window. At this point it is important to save the stack otherwise the reduced IDE returns when the file is next opened.

While this is a bug I appreciate that my report is to vague to be able to assist in tracking it down which is why I have not raised a bug report. So I’m posting to see if anyone else sees this.

Here are my settings for the editor :

 ![Screenshot 2026-08-01 at 09.41.17](https://us1.discourse-cdn.com/flex037/uploads/hyperxtalk/original/1X/24f1e781f38cb3a800135fbd8bc404f10a49cc0b.png)

S

---

<div class="post-metadata">

**Author:** ![Emily-Elizabeth](https://sea1.discourse-cdn.com/flex037/user_avatar/hyperxtalk.discourse.group/emily-elizabeth/32/6_2.png) [@Emily-Elizabeth](https://hyperxtalk.discourse.group/u/Emily-Elizabeth)\
**Post date:** [August 1, 2026, 10:44am UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164/2 "2026-08-01T10:44:48Z")

</div>

Thank you for the feedback. It is not something I have ever seen using either LiveCode or HyperXTalk, mind you though I do not use the IDE all that much lately, so it could be related to how long one is in the IDE. Has anyone else have this happen to them?

---

<div class="post-metadata">

**Author:** ![Skids](https://sea1.discourse-cdn.com/flex037/user_avatar/hyperxtalk.discourse.group/skids/32/106_2.png) [@Skids](https://hyperxtalk.discourse.group/u/Skids)\
**Post date:** [August 2, 2026, 9:26am UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164/3 "2026-08-02T09:26:41Z")

</div>

> [@Emily-Elizabeth](#):
>
> so it could be related to how long one is in the IDE.

Exactly so. I suspect and this is a wild guess that somewhere deep in the IDE a buffer is not being emptied which results in a cascade of odd errors occurring that do not stop the IDE but make it unreliable.

One additional symptom is breakpoints stop working in one of two ways: either execution does not stop or it does but single stepping from that point does not work. Both are solved by quitting and restarting xtalk.

Real “fun” can happen with datagrids when it seems to me that the message path gets very confused and just peters out.

I’ve adopted the policy of restarting every 40 minutes or so and having a button that opens all the scripts of containers that I am interested in - typically the main stack and its sub stacks. I also employ an auto backup plugin that makes a back up every few minutes if it detects that a script in a stack has changed.

S

---

<div class="post-metadata">

**Author:** ![mwieder](https://sea1.discourse-cdn.com/flex037/user_avatar/hyperxtalk.discourse.group/mwieder/32/37_2.png) [@mwieder](https://hyperxtalk.discourse.group/u/mwieder)\
**Post date:** [August 2, 2026, 4:38pm UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164/4 "2026-08-02T16:38:51Z")

</div>

Have to say I’ve never seen this behavior.

---

<div class="post-metadata">

**Author:** ![Skids](https://sea1.discourse-cdn.com/flex037/user_avatar/hyperxtalk.discourse.group/skids/32/106_2.png) [@Skids](https://hyperxtalk.discourse.group/u/Skids)\
**Post date:** [August 3, 2026, 5:59am UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164/5 "2026-08-03T05:59:11Z")

</div>

“Never”? I am really surprised. Perhaps its down to the types of applications we write. Many of my applications interact with the file system on Mac OS reading data into arrays. These arrays get large and are often passed between handlers by reference. While debugging the code is run and stopped at breakpoints typically to check values. At some point during a debug session the IDE will likely enter an unstable state with symptoms as described above.

One code construct that I use and am not altogether happy about is this:

```auto
On RingMaster
   // AnArray of data has been built, and needs further work.
   // it is a large array so is passed by reference.
   
   Put FirstLevelFunction(tLargeA) into tLargeA
   
end RingMaster

Function FirstLevelFunction @pLargeA
   -- Works on pLargeA
   -- and also calls another function say to change a value
   put x into tKey
   put SecondLevelFunction(tKey,pLargeA) into pLargeA
   return pLargeA
end FirstLevelFunction

Function SecondLevelFunction pKey, @pLargeA
   -- operates on pLargeA
   return pLargeA
end SecondLevelFunction

```

Because the array is being passed by reference the return lines, in the functions, are unnecessary as each function is addressing the original variable in memory rather than a copy. Perhaps a better way is to use commands and rely on the referencing.

Sometime in the past I had some code that used a number of arrays and multiple function calls that became so difficult to edit in the IDE that I stopped passing the arrays and changed them to script local variables which did cure the issue.

My present project is reading metadata from image files (jpeg, Tiff and DNG). It is at the point where the data reading is complete so I may try re-writing a version that replaces functions with commands and another that uses script local variables.

I’m not sure why swapping functions for commands should make any difference as I believe that Xtalk allows functions without return values and commands with return values.

So is my programming style a possible root cause of the issues I see in the IDE?

Simon

---

<div class="post-metadata">

**Author:** ![Brian\_Milby](https://sea1.discourse-cdn.com/flex037/user_avatar/hyperxtalk.discourse.group/brian_milby/32/163_2.png) [@Brian\_Milby](https://hyperxtalk.discourse.group/u/Brian_Milby)\
**Post date:** [August 3, 2026, 12:26pm UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164/6 "2026-08-03T12:26:44Z")

</div>

You need to choose one approach and stick with it. LC Mark would need to say for sure, but I think that returning the array like that is causing it to be copied. It is totally unnecessary too. Values passed are `copy on write` but if you are changing the array using reference is the correct approach.

With small values there probably isn’t much of a difference between function and command. With large return values there will be.

---

<div class="post-metadata">

**Author:** ![Skids](https://sea1.discourse-cdn.com/flex037/user_avatar/hyperxtalk.discourse.group/skids/32/106_2.png) [@Skids](https://hyperxtalk.discourse.group/u/Skids)\
**Post date:** [August 6, 2026, 6:44am UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164/7 "2026-08-06T06:44:25Z")

</div>

> [@mwieder](#):
>
> Have to say I’ve never seen this behavior.

I have just started “refactoring” a previously working application and have discovered a way of throwing the IDE into a version of the odd state that I mention.

I believe that the issues are triggered because I have a new function that has no “return”.

The application is designed to import images from a memory card into a folder structure on a hard drive. When a folder or volume is drag dropped onto a graphic the action triggers a call to a handler to list all files. The list files handlers are being updated to make them more robust and involve replacing older code with newer extracted from other working applications. Here is the handler that is called and is missing the “return”.

```auto
function getAllFiles pStartFolder
   # This function is called from the UI and calls the two handlers that
   # list all the folders and than then all the files in the folders
   # These updated versions use the 'detailed UTF' version of the folder and file names
   
   put getAllFolders(pStartFolder) into tFolderList
   repeat for each line aFolderPath in tFolderList
      put getAllFilesInFolder (pFolder) & cr after tFileList
   end repeat 
end getAllFiles

```

“getAllFolders” lists all the folders below pstartfolder using non-recursive code originally written by Bernd and posted on the LC forum. I am posting the code because someone is bound to ask for it.

```auto
function getAllFolders, pStartFolder
   ## Routine that reads the folder tree below pStartFolder
   local tOldDefault, tFolderRootSearch, tTime, tCollector, tAllFiles, doAllTheseFiles, tFolderArray, tFoldersToSearch
   
   --put the defaultfolder into tOldDefault
   put pStartFolder into tFolderRootSearch
   
   --put the milliseconds into tTime
   
   ## begin of search for subfolders
   put "" into tFolderArray
   put 1 into tFolderArray[tFolderRootSearch]
   
   local tLookForMoreFolders, tFoldersTemp, tSubTemp, tList, tListofFolders
   
   repeat -- will exit when no more folders are found see tFoldersToSearch
      put "" into tFoldersToSearch
      
      put the keys of tFolderArray into tLookForMoreFolders
      repeat for each line aFolder in tLookForMoreFolders
         if tFolderArray[aFolder] is not "" then put aFolder & cr after tFoldersToSearch
         put "" into tFolderArray[aFolder] -- so next time this path will not be searched
      end repeat
      
      # Exit the repeat loop when there are no more folders
      if tFoldersToSearch is "" then exit repeat -- no folder found that has not been looked at
      
      # Process the folders that have been found
      repeat for each line aFolder in tFoldersToSearch
         set the defaultfolder to aFolder
         put "" into tFolderArray[aFolder] -- so next time this path will not be searched
         
         ### New code TO USE detailed-UTF
         --put the folders into tFoldersTemp --old
         put empty into tFoldersTemp
         put (the detailed folders) into tList
         repeat for each line aline in tList
            --put item 1 of aline & cr after tFoldersTemp
            put textDecode(URLDecode(item 1 of aLine),"utf8") & cr after tFoldersTemp
         end repeat
         delete the last char of tFoldersTemp
         
         # tFolderTemp should now be more robust
         
         
         # filter out operating system folders on mac (like "..", or starting with "." to make it invisible)
         filter tFoldersTemp without ".*"
         -- filter without application folders, on the mac application may be pakages
         filter tFoldersTemp without "*.app"
         
         # Check if loop should move onto next folder (aFolder)
         if tFoldersTemp is "" then next repeat
         
         repeat for each line aSubFolder in tFoldersTemp
            put aFolder & slash & aSubFolder into tSubTemp
            put 1 into tFolderArray[tSubTemp] -- next time this path will be searched, at the same time the path is a new key in the array
         end repeat
      end repeat -- exits when the list of folders has been processed
   end repeat -- exits when no more folders are found
   
   put the keys of tFolderArray into tListofFolders
   sort tListofFolders
   ## sort using a count of the slashes counted by function FolderDepth
   ## the decending command ensures the deepest folders are listed first
   sort lines of tListofFolders descending by FolderDepth(last item of each)
   
   return tListofFolders
   
end getAllFolders

```

```auto
function getAllFilesInFolder, pFolder
  local tOldDefault, thePath, tList , tFilesInFolder, tFileSpecs
  put the defaultfolder into tOldDefault --> save the original default folder

  put pFolder into thePath

  # now get all the files and the filepaths
  set the defaultfolder to thePath

  put (the detailed files) into tListFileDetails
  put empty into tFilesInFolder
  repeat for each line aFileDetail in tListFileDetails
     set the cursor to busy -- spins a bit further
     # item 2 is the size of the file in bytes
     put textDecode(URLDecode(item 1 of aFileDetail),"utf8") & cr after tFilesInFolder
  end repeat
  delete the last char of tFilesInFolder

  filter tFilesInFolder without ".*"
  put "jpeg,jpg,tif,tiff,dng" into tValidExtensions

  if tFilesInFolder is not "" then
     repeat for each line aFile in tFilesInFolder
        set the cursor to busy -- spins a bit further
        put GetFileExtn(aFile) into tExtn
        if tExtn is among the items of tValidExtensions then
           put thePath & slash & aFile & return after tFileSpecs
        end if
     end repeat
  end if

  --delete last char of tFileSpecs -- return character
  set the defaultFolder to tOldDefault -- housekeeping
  return tFileSpecs --> list of full filespec,filesize

end getAllFilesInFolder

```

When getAllFiles is called it fails to return. I have placed a breakpoint in the calling handler which stops the code as expected. At this point the IDE is not working as it should: it is not possible to inspect variables by double clicking on them and it is not possible to grab the boundary between script and variables and change its size. I have taken a screen video of the issue; where you see the mouse over variables are the resize control I am I am attempting to get them to work.

[Screen Recording 2026-08-06 at 07.32.29.zip](https://hyperxtalk.discourse.group/uploads/short-url/z2OVe7aaTpzZVP2ylCRULLTx7gv.zip) (6.9 MB)

The recording has to be short to enable it to be posted but what does not come across is that other parts of the IDE are still working. I am able to edit code, apply and run it. So to be clear the IDE has not fully locked up but some normal operations no longer work. I am interested if your copy of HyperXtalk exhibits the same strangeness.

[IngestImages\_DNG\_Workflow.hyperXtalk.zip](https://hyperxtalk.discourse.group/uploads/short-url/m7UFnOC7ESfmRPyRRX6PK6k3iku.zip) (272.6 KB)

The stack file has the error I describe above and probably a few more as yet undiscovered.

Simon

---

<div class="post-metadata">

**Author:** ![Emily-Elizabeth](https://sea1.discourse-cdn.com/flex037/user_avatar/hyperxtalk.discourse.group/emily-elizabeth/32/6_2.png) [@Emily-Elizabeth](https://hyperxtalk.discourse.group/u/Emily-Elizabeth)\
**Post date:** [August 6, 2026, 11:18am UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164/8 "2026-08-06T11:18:05Z")

</div>

> [@Skids](#):
>
> When getAllFiles is called it fails to return. I have placed a breakpoint in the calling handler which stops the code as expected. At this point the IDE is not working as it should: it is not possible to inspect variables by double clicking on them and it is not possible to grab the boundary between script and variables and change its size. I have taken a screen video of the issue; where you see the mouse over variables are the resize control I am I am attempting to get them to work.

I tried your stack in both 0.9.15 and 0.9.16 and the breakpoint does trigger, but I am not seeing any issues with using the script editor, like in your video.

- run the stack, switch to browse mode
- select a folder of images
- breakpoint happens, but I am still able to use the script editor (can resize the variables area, can double-click to access variable data)

Do you have any plugins installed? Try disabling them and see if that clears up the issue. If not, I’m at a loss unless someone else can get it to happen. Oh yeah, what operating system are you on?

---

<div class="post-metadata">

**Author:** ![Skids](https://sea1.discourse-cdn.com/flex037/user_avatar/hyperxtalk.discourse.group/skids/32/106_2.png) [@Skids](https://hyperxtalk.discourse.group/u/Skids)\
**Post date:** [August 6, 2026, 1:51pm UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164/9 "2026-08-06T13:51:17Z")

</div>

I’m using Mac OS 15.7.7 Sequoia.

I was about to write that the issue was being caused because the drag drop operation had not fully completed however your report squashes that idea.

I will disable any plugins that I can find.

S

---

<div class="post-metadata">

**Author:** ![BerndN](https://sea1.discourse-cdn.com/flex037/user_avatar/hyperxtalk.discourse.group/berndn/32/29_2.png) [@BerndN](https://hyperxtalk.discourse.group/u/BerndN)\
**Post date:** [August 6, 2026, 1:56pm UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164/10 "2026-08-06T13:56:50Z")

</div>

The locking of the script editor is only happening when drag/dropping a folder.

This is the same for HXT as for LC.

You can “unlock” the ScriptEditor from the freeze when changing your code in handler “dragDrop”

```auto
If there is a Folder tFirstItem then
put tFirstItem into Field "SourceFolder"
-- report on the number of images to be copied
send "PopulateCount tFirstItem" to me in 20 milliseconds <---
else 

```

Send in time seems to release “dragDroping”

Furthermore change to this

```auto
function getAllFiles pStartFolder
   # This function is called from the UI and calls the two handlers that
   # list all the folders and than then all the files in the folders
   # These updated versions use the 'detailed UTF' version of the folder and file names
   
   put getAllFolders(pStartFolder) into tFolderList
   repeat for each line aFolderPath in tFolderList
      put getAllFilesInFolder (pStartFolder) & cr after tFileList
   end repeat 
end getAllFiles

```

Note that you reference to “pFolder” instead of “pStartFolder”

After these changes dropping a folder worked as expected and the the ScriptEditor was responsive at the breakpoints.

---

<div class="post-metadata">

**Author:** ![Skids](https://sea1.discourse-cdn.com/flex037/user_avatar/hyperxtalk.discourse.group/skids/32/106_2.png) [@Skids](https://hyperxtalk.discourse.group/u/Skids)\
**Post date:** [August 6, 2026, 2:19pm UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164/11 "2026-08-06T14:19:34Z")

</div>

Thanks BerndN for the tip. I thought I had found a recipe for the IDE strangeness that I reported above. However, unfortunately it does appear to be down to the drag drop handler not fully completing. Mind you when it does complete the IDE remains blocked but can be released by going to IDE settings. However, I will add the “send in time” and move on.

As you have discovered the code base needs work and is the result of inserting similar but slightly different handlers from other applications.

I apologise for wasting everyones time.

Simon ☹

---

<div class="post-metadata">

**Author:** ![Brian\_Milby](https://sea1.discourse-cdn.com/flex037/user_avatar/hyperxtalk.discourse.group/brian_milby/32/163_2.png) [@Brian\_Milby](https://hyperxtalk.discourse.group/u/Brian_Milby)\
**Post date:** [August 6, 2026, 2:26pm UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164/12 "2026-08-06T14:26:22Z")

</div>

I will say that a function without a `return` seems to be a mistake.

---

<div class="post-metadata">

**Author:** ![Skids](https://sea1.discourse-cdn.com/flex037/user_avatar/hyperxtalk.discourse.group/skids/32/106_2.png) [@Skids](https://hyperxtalk.discourse.group/u/Skids)\
**Post date:** [August 6, 2026, 3:12pm UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164/13 "2026-08-06T15:12:21Z")

</div>

It is or was.

---

<div class="post-metadata">

**Author:** ![Emily-Elizabeth](https://sea1.discourse-cdn.com/flex037/user_avatar/hyperxtalk.discourse.group/emily-elizabeth/32/6_2.png) [@Emily-Elizabeth](https://hyperxtalk.discourse.group/u/Emily-Elizabeth)\
**Post date:** [August 6, 2026, 3:25pm UTC](https://hyperxtalk.discourse.group/t/issue-with-the-ide/164/14 "2026-08-06T15:25:03Z")

</div>

> [@Skids](#):
>
> I apologise for wasting everyones time.

Never a waste of time to ask a question. 🙂